Mercurial > hg > portage

comparison dev-python/qscintilla-python/qscintilla-python-2.7.2-r1.ebuild @ 371:08cf4b4c2316

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
add a qscintilla ebuild that is python 3.4 aware
author Dirk Olmes <dirk@xanthippe.ping.de>
date Mon, 24 Nov 2014 11:28:15 +0100
parents
children
comparison
equal deleted inserted replaced
370:f4ed803dfb89 371:08cf4b4c2316
1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-python/qscintilla-python/qscintilla-python-2.7.2.ebuild,v 1.10 2014/11/20 00:41:25 pesa Exp $
4
5 EAPI=5
6 PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3,3_4} )
7
8 inherit eutils multilib python-r1 toolchain-funcs
9
10 MY_P=QScintilla-gpl-${PV}
11
12 DESCRIPTION="Python bindings for Qscintilla"
13 HOMEPAGE="http://www.riverbankcomputing.co.uk/software/qscintilla/intro"
14 SRC_URI="mirror://sourceforge/pyqt/${MY_P}.tar.gz"
15
16 LICENSE="|| ( GPL-2 GPL-3 )"
17 SLOT="0"
18 KEYWORDS="alpha amd64 ia64 ppc ppc64 sparc x86"
19 IUSE="debug"
20
21 DEPEND="
22 ${PYTHON_DEPS}
23 >=dev-python/sip-4.12:=[${PYTHON_USEDEP}]
24 =dev-python/PyQt4-4.10*[X,${PYTHON_USEDEP}]
25 dev-qt/qtcore:4
26 dev-qt/qtgui:4
27 ~x11-libs/qscintilla-${PV}:=
28 "
29 RDEPEND="${DEPEND}"
30
31 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
32
33 S=${WORKDIR}/${MY_P}/Python
34
35 src_prepare() {
36 python_copy_sources
37 }
38
39 src_configure() {
40 configuration() {
41 local myconf=(
42 "${PYTHON}" configure-old.py
43 --apidir="${EPREFIX}"/usr/share/qt4/qsci
44 --destdir="$(python_get_sitedir)"/PyQt4
45 --sipdir="${EPREFIX}"/usr/share/sip
46 -n "${EPREFIX}"/usr/include/qt4
47 -o "${EPREFIX}"/usr/$(get_libdir)/qt4
48 -p 4
49 --no-timestamp
50 $(use debug && echo --debug)
51 )
52 echo "${myconf[@]}"
53 "${myconf[@]}" || die
54 }
55 python_parallel_foreach_impl run_in_build_dir configuration
56 }
57
58 src_compile() {
59 compilation() {
60 emake CC="$(tc-getCC)" CXX="$(tc-getCXX)" LINK="$(tc-getCXX)"
61 }
62 python_foreach_impl run_in_build_dir compilation
63 }
64
65 src_install() {
66 python_foreach_impl run_in_build_dir default
67 }