--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/dev-java/maven-bin/maven-bin-3.0.4.ebuild	Sat Jan 21 13:36:46 2012 +0100
@@ -0,0 +1,49 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/maven-bin/maven-bin-3.0.2.ebuild,v 1.1 2011/01/15 12:25:40 fordfrog Exp $
+
+inherit java-pkg-2
+
+MY_PN=apache-${PN%%-bin}
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Project Management and Comprehension Tool for Java"
+SRC_URI="mirror://apache/maven/binaries/${MY_P}-bin.tar.gz"
+HOMEPAGE="http://maven.apache.org/"
+LICENSE="Apache-2.0"
+SLOT="3.0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+RDEPEND=">=virtual/jdk-1.5
+	app-admin/eselect-maven"
+
+IUSE=""
+
+S="${WORKDIR}/${MY_P}"
+
+MAVEN=${PN}-${SLOT}
+MAVEN_SHARE="/usr/share/${MAVEN}"
+
+src_unpack() {
+	unpack ${A}
+
+	rm -v "${S}"/bin/*.bat || die
+	chmod 644 "${S}"/boot/*.jar "${S}"/lib/*.jar "${S}"/conf/settings.xml || die
+}
+
+# TODO we should use jars from packages, instead of what is bundled
+src_install() {
+	dodir "${MAVEN_SHARE}"
+	cp -Rp bin boot conf lib "${D}/${MAVEN_SHARE}" || die "failed to copy"
+
+	java-pkg_regjar "${D}/${MAVEN_SHARE}"/lib/*.jar
+
+	dodoc NOTICE.txt README.txt || die
+
+	dodir /usr/bin
+	dosym "${MAVEN_SHARE}/bin/mvn" /usr/bin/mvn-${SLOT}
+
+	# bug #342901
+	echo "CONFIG_PROTECT=\"${MAVEN_SHARE}/conf\"" > "${T}/25${MAVEN}" || die
+	doenvd "${T}/25${MAVEN}"
+}