# HG changeset patch
# User Dirk Olmes <dirk@xanthippe.ping.de>
# Date 1416380049 -3600
# Node ID 9c0597d116b53c3c6bf7117a97230d3ba72a302a
# Parent  955e226c86a98ed5060565e7f5d0a5795a3951d0
add a ebuild for the latest and greatest exaile release

diff -r 955e226c86a9 -r 9c0597d116b5 media-sound/exaile/Manifest
--- a/media-sound/exaile/Manifest	Tue Nov 11 09:54:43 2014 +0100
+++ b/media-sound/exaile/Manifest	Wed Nov 19 07:54:09 2014 +0100
@@ -1,2 +1,2 @@
-DIST exaile-0.3.1.1.tar.gz 1897993 RMD160 38f6d4541ddda4e25c8fcfe2a721e23defeb1b54 SHA1 e83b5e8034f179a8f571fdd8c3493f8f73ea510d SHA256 e785e08dcf4b7392cfd608118732f2365e9cd5374eed7d473e814208f23e1e3c
-EBUILD exaile-0.3.1.1.ebuild 1752 RMD160 0001e1861686e57362914573154fbc10c0f88e61 SHA1 db3b9b45bc4e36357c1cf64e1629a9cdcc7ecd98 SHA256 eac49f728ee4e86f183e9f0e583d8a98b75901eb278573f5b288d5595e1fc275
+DIST 3.4.2.tar.gz 3373802 SHA256 0e280c317871e37cbe9db8d54d37a5bee99cf36ebd0f55048e41787d0461e4bf SHA512 1a13585afc4eaa2b03c3be0bd25394e8c6df824999b676349f6efeabe9286d7c773eaf5938d7a644e9facb9b6184c02cc465fe1ec0d22057ab2cb8a521357312 WHIRLPOOL 8e17d226ca5f7d996ee66cac21f8c9c6c3244a6387511f1ae8837987cd9e7eba0e54cd52d765a71e64d7f9594138df85d0308e3b52add4c57c1ab69035261b5b
+EBUILD exaile-3.4.2.ebuild 1251 SHA256 e8d9d0c319b62107dae35c728f2e16563cee1e558d15b60148f5a50777be109d SHA512 ba57d3a01890cf43219708dce499b31713cab5409200259f29af0297aa743fccf170ac4492c1dc3fb64769011d4ed77307216187765e743a7e40e7e2cf42a4b0 WHIRLPOOL 4c6d3b0bb11ecca896a2821362b7bbc302b40feeb71a1da1d70f29e39b8b1affb352e98351dafddda87bbe4fa5534eb126e6d824d5c07a4af65dcaa4e86cbee1
diff -r 955e226c86a9 -r 9c0597d116b5 media-sound/exaile/exaile-0.3.1.1.ebuild
--- a/media-sound/exaile/exaile-0.3.1.1.ebuild	Tue Nov 11 09:54:43 2014 +0100
+++ /dev/null	Thu Jan 01 00:00:00 1970 +0000
@@ -1,76 +0,0 @@
-# Copyright 1999-2010 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/exaile/Attic/exaile-0.3.1.1.ebuild,v 1.2 2010/08/14 17:33:32 ssuominen dead $
-
-EAPI=2
-
-PYTHON_DEPEND="2:2.6"
-PYTHON_USE_WITH="sqlite"
-
-inherit fdo-mime multilib python
-
-DESCRIPTION="a media player aiming to be similar to AmaroK, but for GTK+"
-HOMEPAGE="http://www.exaile.org/"
-SRC_URI="http://launchpad.net/exaile/0.3.1/${PV}/+download/${P}.tar.gz"
-
-LICENSE="GPL-2 GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc ~sparc x86"
-IUSE="cddb libnotify nls"
-
-RDEPEND="dev-python/dbus-python
-	>=media-libs/mutagen-1.10
-	>=dev-python/pygtk-2.14
-	>=dev-python/pygobject-2.18
-	dev-python/gst-python:0.10
-	media-libs/gst-plugins-good:0.10
-	media-plugins/gst-plugins-meta:0.10
-	libnotify? ( dev-python/notify-python )
-	cddb? ( dev-python/cddb-py )"
-DEPEND="nls? ( dev-util/intltool
-	sys-devel/gettext )"
-
-# Required python 'mox' module missing wrt #315589
-RESTRICT="test"
-
-pkg_setup() {
-	python_set_active_version 2
-}
-
-src_prepare() {
-	sed -i \
-		-e "s:exec python:exec $(PYTHON):" \
-		exaile tools/generate-launcher || die
-}
-
-src_compile() {
-	if use nls; then
-		emake locale || die
-	fi
-}
-
-src_install() {
-	local _no_locale
-	use nls || _no_locale=_no_locale
-
-	emake PREFIX="/usr" LIBINSTALLDIR="/$(get_libdir)" DESTDIR="${D}" \
-		install${_no_locale} || die
-
-	dodoc README
-
-	insinto /usr/share/exaile/data
-	doins -r data/migrations || die
-}
-
-pkg_postinst() {
-	python_need_rebuild
-	python_mod_optimize /usr/$(get_libdir)/${PN}
-	fdo-mime_desktop_database_update
-	fdo-mime_mime_database_update
-}
-
-pkg_postrm() {
-	python_mod_cleanup /usr/$(get_libdir)/${PN}
-	fdo-mime_desktop_database_update
-	fdo-mime_mime_database_update
-}
diff -r 955e226c86a9 -r 9c0597d116b5 media-sound/exaile/exaile-3.4.2.ebuild
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/media-sound/exaile/exaile-3.4.2.ebuild	Wed Nov 19 07:54:09 2014 +0100
@@ -0,0 +1,58 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_6,2_7} )
+PYTHON_REQ_USE="sqlite"
+
+inherit fdo-mime multilib python-r1
+
+DESCRIPTION="a media player aiming to be similar to AmaroK, but for GTK+"
+HOMEPAGE="http://www.exaile.org/"
+SRC_URI="https://github.com/exaile/exaile/archive/${PV}.tar.gz"
+
+LICENSE="GPL-2 GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="cddb libnotify nls"
+
+RDEPEND="dev-python/dbus-python
+	>=media-libs/mutagen-1.10
+	>=dev-python/pygtk-2.17
+	>=dev-python/pygobject-2.18:2
+	dev-python/gst-python:0.10
+	media-libs/gst-plugins-good:0.10
+	media-plugins/gst-plugins-meta:0.10
+	libnotify? ( dev-python/notify-python )
+	cddb? ( dev-python/cddb-py )"
+DEPEND="nls? ( dev-util/intltool
+	sys-devel/gettext )"
+
+RESTRICT="test" #315589
+
+src_compile() {
+	if use nls; then
+		emake locale || die
+	fi
+}
+
+src_install() {
+	emake \
+		PREFIX=/usr \
+		LIBINSTALLDIR=/$(get_libdir) \
+		DESTDIR="${D}" \
+		install$(use nls || echo _no_locale) || die
+
+	dodoc FUTURE || die
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}