Mercurial > hg > portage

changeset 440:d27b7787b1f8

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
revive the eric ebuild - cannot update due to hard masked dependencies
author Dirk Olmes <dirk@xanthippe.ping.de>
date Wed, 26 Apr 2017 08:38:22 +0200
parents 8bf346bb0f28
children e493bd4a6f5e
files dev-util/eric/Manifest dev-util/eric/eric-16.12.ebuild
diffstat 2 files changed, 69 insertions(+), 0 deletions(-) [+]
line wrap: on
line diff
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/dev-util/eric/Manifest	Wed Apr 26 08:38:22 2017 +0200
@@ -0,0 +1,2 @@
+DIST eric6-16.12.tar.gz 18764980 SHA256 cfb70ef9c68fe88ea0752bc0141efc04c7fce118fd9166ec5ef57dfe23a492c6 SHA512 53506c52e289db141abf8faf1a90a7b1a2d32ab6932d6254aa8cb3e69ed8b78932d648c8625335cfae187053c3f7d3adf84f60867591ab804215b645a1719340 WHIRLPOOL 085a0048805d33b8a0426e743eb112643a6aa54668185eeeedb0ecadf68ae7f41aae98e0f853a0183e62b4c82ffcad7aca94d97087d00d10b57c0cdb5f3d5eb2
+EBUILD eric-16.12.ebuild 1694 SHA256 fcfd37575d54ec5744053756c657496a3a20f449aeb5144170ad2f6881dc1a81 SHA512 33ee494531ae4524447f0f5108ce5ff77addaffddf0cf0ddf936a9f4a4ec5f8ba0f65b0e236065aa6834335bcb7f7f13f95e0e0d08ef27fab685e8ae95450dc4 WHIRLPOOL 6555917598ac4584cc5cebed81be7e4e58896fbc8ae9c885f2f4130fad0481e642ec187952497ef39d89c9f91caa4c6097c86f9bd9ae4624bd490387e9bed692
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/dev-util/eric/eric-16.12.ebuild	Wed Apr 26 08:38:22 2017 +0200
@@ -0,0 +1,67 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+PYTHON_REQ_USE="sqlite,xml"
+
+inherit python-single-r1
+
+DESCRIPTION="A full featured Python IDE using PyQt and QScintilla"
+HOMEPAGE="http://eric-ide.python-projects.org/"
+LICENSE="GPL-3"
+SLOT="6"
+
+MY_P=${PN}${SLOT}-${PV}
+SRC_URI="mirror://sourceforge/eric-ide/${PN}${SLOT}/stable/${PV}/${MY_P}.tar.gz"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	${PYTHON_DEPS}
+	>=dev-python/sip-4.14.3[${PYTHON_USEDEP}]
+	>=dev-python/PyQt4-4.10[${PYTHON_USEDEP},X,help,sql,svg,webkit]
+	>=dev-python/qscintilla-python-2.8[qt4(+),${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}
+	>=dev-python/chardet-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/coverage-4.1.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.1.3[${PYTHON_USEDEP}]
+	!dev-util/eric:4
+	!dev-util/eric:5
+"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=(changelog README.rst THANKS)
+
+src_prepare() {
+	default
+
+	# Delete internal copies of dev-python/chardet and dev-python/pygments
+	rm -fr eric/ThirdParty/{CharDet,Pygments} || die
+
+	# Delete internal copy of dev-python/coverage
+	rm -fr eric/DebugClients/Python{,3}/coverage || die
+	sed -i -e 's/from DebugClients\.Python3\?\.coverage/from coverage/' \
+		$(grep -lr 'from DebugClients\.Python3\?\.coverage' .) || die
+
+	# Fix desktop files (bug 458092)
+	sed -i -re '/^Categories=/s:(Python|QtWeb):X-&:g' eric/eric6{,_{,web}browser}.desktop || die
+}
+
+src_install() {
+	"${PYTHON}" install.py \
+		-b "${EPREFIX}/usr/bin" \
+		-d "$(python_get_sitedir)" \
+		-i "${D}" \
+		-c \
+		-z \
+		--pyqt=4 \
+		|| die
+
+	python_optimize
+	einstalldocs
+}